home *** CD-ROM | disk | FTP | other *** search
/ MacUser Mac Bin 25 / MACUSER-MACBIN25-1995-12.ISO.7z / MACUSER-MACBIN25-1995-12.ISO / 本誌連動 / HyperCard office.9512⁄CD / 95-10 < prev    next >
Text File  |  1995-10-01  |  12KB  |  171 lines
  1. アイドルを捜そう
  2.  
  3. このところ少しハードな内容が続いたので、今回はアクセルをゆるめてアイドル運転をすることにしよう。取り上げるテーマも、時間を持て余しているＣＰＵの、アイドルタイムの利用法だ。
  4.  
  5. --
  6. オフィスにはアイドルがいっぱい
  7.  
  8. 　オフィスに着いてから帰るまで、たとえば９時間コンピュータの電源をオンにしているとして、その間ユーザーが画面に向かって作業をしている時間はどれくらいあるだろうか。しょっちゅう使っているようでも、実際にキーボードにさわっている時間は通算してせいぜい数十分程度だろう。データインプットの専門家など特別な人は別として、数時間に上るというのは余り考えられない。しかも、ワープロなどのアプリケーションの場合、コンピュータから見るとほとんどの時間はインプットの待ち状態。オフィスで最も活躍するアプリケーションがスクリーンセイバーというのはブラックユーモアだが、多くの場合、真実である。
  9. 　この待ち時間を利用して何か有効な作業を行わせることができないか。今回は、アイドルタイムの活用方法を検討してみる。
  10.  
  11. --
  12. idleメッセージ
  13.  
  14. 　ハイパーカードは全てメッセージによって働いている。ボタンをクリックするとmouseUpというメッセージが送られるし、メニューを選ぶとdoMenuというメッセージが発行されて命令が実行される。ユーザーはメッセージボックスから命令を打ち込むことで、直接メッセージを送ることも可能だ。そして、こうしたメッセージが何もない待機状態の間、ハイパーカードでは、常にidleというメッセージがカードに対して送られている。（図1）
  15. 　「メッセージウォッチャ」を開いてみると( _*注1_ )、画面1のように連続したidleメッセージが確認できるはずだ。このidleの発行は、ユーザが指示をしなくても、ハイパーカードが勝手に行ってくれる作業である。従って、このメッセージをうまく使うと、コンピュータの空き時間に仕事を自動的に実行させることが可能になる。
  16.  
  17. --
  18. idleによる自動操作（復習）
  19.  
  20. 　８月号で検討した「会議室予約システム」では、このidleを利用したスタックの強制解放の仕組みを組み込んでいた( _95-08:会議室予約スタック_ 参照)。一定時間入力がなかったら自動的にスタックを閉じる命令を発することで、共有環境での資源の有効な利用をはかるというものだった。この仕組みを少し復習してみよう（ _リスト1_ ）。
  21. 　まず、スタックを開いた時点でタイムリミットの時刻をグローバル変数に保存する（4行目）。そして、バックグラウンドにおいたon idleハンドラで、現在時刻がタイムリミットを越えていないかを監視する（9行目）。もし越えていたら、その時点でスタックを閉じる命令を発してスタックを解放する。
  22. 　ここでのポイントは、命令の実施時刻、つまりタイムリミットをグローバル変数に設定するというところだ。単に空き時間を利用するというのではなく、コンピュータの内蔵時計をチェックすることで、特定の仕事を特定のタイミングで実施させる。この時刻監視の構造をうまく設計できれば、自動操作システムは半分できたも同然なのだ。
  23. 　以上をまとめると、idleによる自動操作の公式は
  24. 　❶命令を実施する時刻を設定（グローバル変数）し
  25. 　❷idleメッセージのたびに現在時刻をチェックし
  26. 　❸指定時刻になったら命令を実行する
  27. ということになる。
  28.  
  29. --
  30. 定時作業の自動化
  31.  
  32. 　定期的に行う作業なら、グローバル変数を使わず、指定日時をスクリプトに直接書き込んでも良い。このとき注意しなければならないのは、時刻の書式である。マッキントッシュは時刻を12時制、24時制のどちらにもできるので、
  33.     if the time is "15:00" then
  34. のようなチェックでは正しく働かない可能性が残る( _*注2_ )。これをクリアするには、 _convert_ 命令で時刻をいったんdateItems形式にすればよい。例えば
  35.     put "95.09.18" into theDate
  36.     convert theDate to dateItems
  37. とすると、変数theDateは"1995,9,18,0,0,0,2"という形になる。これは順番に年,月,日,時,分,秒,曜日というアイテムに日付が変換されたもので、時刻が常に24時制で比較できる上に、曜日も調べられるというおまけが付く。
  38. 　これを利用すると、例えば「毎週月曜日の午前中にサーバーに報告書ファイルを提出する」というルールが守られているか、自動チェックを行うことができる（ _リスト2_ ）。5行目で現在時刻（the time）を変換し、6行目で曜日（item 7）、時（item 4）、分（item 5）を調べる。月曜日の午後1時になったら7行目で指定ファイルが提出されているかどうかを確認するのだ。
  39. 　なお、2〜4行目で行なっているのは、同じ警告を必要以上に繰り返さないための手続きである。idleメッセージは1秒に何十回も発行されているから、「午後1時0分に実行する」と指定された命令は、1時1分になるまでの間、延々と繰り返されてしまう。そこで、命令を処理するたびに現在時刻（何時何分）をグローバル変数lastCheckTimeにセットしておき（4行目）、次にidleが巡ってきたときに変数と現在時刻を比較して、同じ時刻なら処理をキャンセルするのである。こうすることで、このチェック命令は1分間に1回だけ実行されるようになるわけだ。
  40. 　繰り返すが、自動操作は実行タイミングの設定がキーポイントである。サンプルとして、指定時刻や指定秒後に命令を実行するidleハンドラを作成するスタック（画面2）を用意したので、実際にその働きを確認してみて欲しい。
  41.  
  42. --
  43. ハイパーカードを遠隔操作
  44.  
  45. 　idleを使うと、自動作業だけでなく、別のコンピュータを遠隔操作するというアクロバティックな仕掛けを作ることができる。
  46. 　この手法は、原理的には前節で述べた定時自動操作と違いはない。常にidleメッセージを監視し、ある条件が満たされたら命令を実行する。異なるのは、命令とそれを実施するタイミングをあらかじめ決めておかず、外部から命令内容とその実行指示を送るという点だ。
  47. 　実行時に命令文を変数として与える方法は、８月号のネットワーク活用の記事の中でも紹介した。doを使って外部ファイルに保存した文字列を実行するという手法である。すなわち、ファイルを読み出す関数をReadFile()とすれば
  48.     do ReadFile(<command file>)
  49. という形になる。命令はスクリプトに書き込まず、外部ファイル<command file>にテキストとして用意しておく。
  50. 　命令を与える方法が決まったら、次の問題は実施のタイミングである。外部ファイルに実行内容があるのだから、そのファイルの更新時刻を基準にタイミングを判断するのが分かり易い。ここではidleのたびに<command file>の更新時刻を調べ、ファイルが新しくなっていたら、そのファイルを読み出してdoで実行することにしよう。指示を与える側から言えば、ファイルを更新することで遠隔コンピュータに作業を実行させられるということだ（図2）。
  51. 　残念ながらハイパートークにはファイルの更新時刻を調べる関数は用意されていないので、XFCNを使う。スタックHyperLauncherに用意したFileInfo()は、引数にファイル名を与えると、4番目のアイテムとしてファイルの更新時刻をsecondsフォーマットで返す。これを使って、前回の命令を実行した時刻と比較をするのである。
  52.  
  53. --
  54. 遠隔操作スクリプトの実際
  55.  
  56. 　以上をまとめたのが _リスト3_ である。2〜4行は、idleの処理を頻繁に行いすぎないようにする前処理のバリエーション。この例では、一度処理を行ったら60秒間はidleが送られてもパスするという設定になっている（ _リスト2_ と比較してみよう）。
  57. 　5行目以降が遠隔操作の部分である。命令ファイルの更新時刻を調べ、前回行った命令の時刻（「LastCommand」というフィールドに保存してある）と比較する。ファイルが変更されていなければ、その命令は既に実行済みということになるので、何もせずに通り過ぎる。もしファイルが新しくなっていたら、新たな指示が送られたということだ。まずこの時刻をフィールド「LastCommand」に記録し（つまり実施済みであることを記録する）、そのうえでファイルをReadFile()で読み出してdo命令で実行する。
  58. 　ごく短い簡単なスクリプトだが、これでもちゃんと遠隔操作はできる。命令を保存ファイルを更新して保存するだけで、全てのコンピュータに1分以内に指示がきちんと届く。何台ものコンピュータが次々にこの指示に反応していくのを見るのは、なかなか面白いものだ。
  59.  
  60. --
  61. 電子速達メール
  62.  
  63. 　最後の応用として、メッセージの即時送信を考えておこう。ここまできたらあとは簡単。前項の遠隔操作のスクリプトを、命令ファイルを読み出す代わりにメッセージファイルを調べて表示するように変更すると、たちどころに速達メールができあがる（画面3）。 _リスト4_ はほとんどリスト3と同じ構造である。フィールドに記録した時刻よりメッセージファイルが新しければ、メッセージ表示用のカードに移動してファイルの内容をテキストフィールドに書き込む。最後に
  64.     open long name of HyperCard
  65. としているのは、この命令でハイパーカードをフォアグラウンドに呼び出し、ほかの作業をしているときでも強制的にメッセージを読んでもらおうという戦略である（漢字Talk7以降のみ有効）。
  66. 　6、7月号でスタック起動時にメッセージを表示する方法を紹介したが( _95-06:電子掲示板_ 及び _95-07:電子掲示板との連動_ 参照)、場合によってはすぐにメッセージを知らせたいときもあるだろう。両者を組み合わせて使うと効果的な情報伝達ができると思う。
  67.  
  68. 　ハイパーカードのスクリプトは別のアプリケーションのバックグラウンドでも働くので、これらの機能を実現するにはハイパーカードが起動していさえすればよい。逆に言うと、ハイパーカードが常に立ち上がっていなければ、当然のことながらこの便利な自動作業や遠隔操作は使えないことになる。このためだけでも、6月号で述べたようなローンチャ( _95-06:ハイパーローンチャ_ )をハイパーカードで作成し、常に起動しておく意義は十分にあると思う。ハイパーカードはいつでも使えるように、起動項目に入れておこう。これが快適なハイパーカード・オフィスの基本である。
  69.  
  70. --
  71. *注1
  72.  
  73. メッセージボックスから"mw"という命令を実行して開くことができる
  74.  
  75. --
  76. *注2
  77.  
  78. ハイパートークでは時刻も文字列として扱われるので、15:00と3:00 PMは異なるものとなってしまう。
  79.  
  80. --
  81. リスト1
  82.  
  83.  1: on openStack
  84.  2:   global TimeOut
  85.  3:   ...
  86.  4:   put the seconds + 300 into TimeOut -- 5分間をタイムリミットとする場合
  87.  5:   ...
  88.  6: end openStack
  89.  
  90. -- idleメッセージを監視する。バックグラウンドに置く。
  91.  7: on idle
  92.  8:   global TimeOut
  93.  9:   if the seconds > TimeOut then
  94. 10:     go stack "HyperLauncher" -- pop cdなどでもよい。スタックを強制的に閉じる。
  95. 11:   else
  96. 12:     pass idle
  97. 13:   end if
  98. 14: end idle
  99.  
  100. --
  101. リスト2
  102.  
  103.  1: on idle
  104.  2:   global lastCheckTime
  105.  3:   if the time is NOT lastCheckTime then
  106.  4:     put the time into lastCheckTime
  107.  5:     convert the time to dateItems --この場合は結果が変数itに納められる
  108.  6:     if item 7 of it is 2 AND item 4 of it is 13 AND item 5 of it is 0 then
  109.  7:       if there is NOT a file <報告書のファイル名>
  110.  8:       then answer "報告書が提出されていません！"
  111.  9:     end if
  112. 10:   end if
  113. 11:   ...
  114. 12:   pass idle -- _pass_ の解説参照
  115. 13: end idle
  116.  
  117. --
  118. リスト3
  119.  
  120.  -- fld "LastCommand"は「 _テキストを共有_ 」に設定しておく
  121.  1: on idle
  122.  2:   global nextAccess
  123.  3:   if the seconds < nextAccess then pass idle
  124.  4:   put the seconds + 60 into nextAccess
  125.  5:   get FileInfo(<command file>)
  126.  6:   if item 4 of it > fld "LastCommand" then 
  127.  7:     put item 4 of it into fld "LastCommand"
  128.  8:     do ReadFile(<command file>)
  129.  9:   end if
  130. 10:   ...
  131. 11:   pass idle
  132. 12: end idle
  133.  
  134. --
  135. リスト4
  136.  
  137.  -- fld "LastMessage"は「テキストを共有」に設定しておく
  138.  1: on idle
  139.  2:   global nextAccess
  140.  3:   if the seconds < nextAccess then pass idle
  141.  4:   put the seconds + 60 into nextAccess
  142.  5:   get FileInfo(<message file>)
  143.  6:   if item 4 of it > fld "LastMessage" then
  144.  7:     put item 4 of it into fld "LastMessage"
  145.  8:     go cd "MessageBoard"
  146.  9:     put ReadFile(<message file>) into fld "MessageText"
  147. 10:     open long name of HyperCard
  148. 11:   end if
  149. 12:   ...
  150. 13:   pass idle
  151. 14: end idle
  152.  
  153.  
  154. --
  155. convert
  156.  
  157. 本文でも説明したとおり、時刻の表現形式を変換する命令。変換できるフォーマットはdateItemsのほかにseconds, short date, long date, short timeなどがあり、場合によって使い分けることができる。特に、時刻の比較をするとき、ハイパーカードでは文字列形式（the date, the timeなど）のまま前後を比べることはできないが、いったんsecondsフォーマットにするとこれが可能になり、大変便利である。今回の遠隔操作でも、ファイルの更新時刻をseconds形式で取得することで、ファイルが新しいかどうかの比較を行っている。
  158.  
  159. --
  160. pass
  161.  
  162. サンプルリストで全て最後にpass idleという１行が加えられているのに気付かれただろうか。ハイパーカードはカード、バックグラウンド、スタックといった階層構造になっていて、メッセージはこの順序に伝えられて行き、ハンドラが見つかったところで処理される。カードにon idleハンドラがあればidleメッセージはここで処理され、バックグラウンドには届かない。このとき、pass idleとしておくと、このメッセージが更に次の階層、この場合はバックグラウンドにも送られる。通常の処理をバックグラウンドで行っており、カードで特別な処理を行った上で通常の処理もこなしたいときは、このようにpass idleを置いておく必要がある。
  163. ハンドラの途中にこのpassを置くと、メッセージは直ちに次の階層に送られ、残りのハンドラは処理されない。リスト3の3行目で、次の命令実施時刻になっていないときにpass idleとしているのはこのためである。
  164. 一般に、openCard, openStackなどの汎用ハンドラは最後にpassしておくことが多い。
  165.  
  166. --
  167. テキストを共有
  168.  
  169. バックグラウンドフィールドの属性の一つ。通常バックグラウンドフィールドに記録する内容はカードごとに異なるが、これがチェックされていると、同じ内容が全てのカードで共有される。リスト3,4でファイルの更新時刻をどのカードからでも確認できるようにするためには、前回のファイル更新時刻を「テキストを共有」しているバックグラウンドフィールドに保存しておかなければならない。
  170. --
  171.